-
Notifications
You must be signed in to change notification settings - Fork 6
/
advec_cell_kernel.cuf
579 lines (481 loc) · 20.5 KB
/
advec_cell_kernel.cuf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
!Crown Copyright 2012 AWE.
!
! This file is part of CloverLeaf.
!
! CloverLeaf is free software: you can redistribute it and/or modify it under
! the terms of the GNU General Public License as published by the
! Free Software Foundation, either version 3 of the License, or (at your option)
! any later version.
!
! CloverLeaf is distributed in the hope that it will be useful, but
! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
! FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
! details.
!
! You should have received a copy of the GNU General Public License along with
! CloverLeaf. If not, see http://www.gnu.org/licenses/.
!> @brief Fortran cell advection kernel.
!> @author Wayne Gaudin
!> @details Performs a second order advective remap using van-Leer limiting
!> with directional splitting.
MODULE advec_cell_kernel_module
CONTAINS
attributes(global) SUBROUTINE advec_cell_kernel_1x(x_min, &
x_max, &
y_min, &
y_max, &
sweep_number,&
volume, &
vol_flux_x, &
vol_flux_y, &
pre_vol, &
post_vol)
IMPLICIT NONE
INTEGER, value :: x_min,x_max,y_min,y_max
INTEGER, value :: sweep_number
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: volume
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: vol_flux_x
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: vol_flux_y
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_vol
integer :: j, k
j = (blockIdx%x-1)*blockDim%x + threadIdx%x + x_min-3
k = (blockIdx%y-1)*blockDim%y + threadIdx%y + y_min-3
IF(sweep_number.EQ.1)THEN
if (j <= x_max+2 .and. k <= y_max+2) then
pre_vol(j,k)=volume(j,k)+(vol_flux_x(j+1,k )-vol_flux_x(j,k)+vol_flux_y(j ,k+1)-vol_flux_y(j,k))
post_vol(j,k)=pre_vol(j,k)-(vol_flux_x(j+1,k )-vol_flux_x(j,k))
end if
ELSE
if (j <= x_max+2 .and. k <= y_max+2) then
pre_vol(j,k)=volume(j,k)+vol_flux_x(j+1,k)-vol_flux_x(j,k)
post_vol(j,k)=volume(j,k)
end if
ENDIF
END SUBROUTINE advec_cell_kernel_1x
attributes(global) SUBROUTINE advec_cell_kernel_1y(x_min, &
x_max, &
y_min, &
y_max, &
sweep_number,&
volume, &
vol_flux_x, &
vol_flux_y, &
pre_vol, &
post_vol)
IMPLICIT NONE
INTEGER, value :: x_min,x_max,y_min,y_max
INTEGER, value :: sweep_number
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: volume
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: vol_flux_x
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: vol_flux_y
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_vol
integer :: j, k
j = (blockIdx%x-1)*blockDim%x + threadIdx%x + x_min-3
k = (blockIdx%y-1)*blockDim%y + threadIdx%y + y_min-3
IF(sweep_number.EQ.1)THEN
if (j <= x_max+2 .and. k <= y_max+2) then
pre_vol(j,k)=volume(j,k)+(vol_flux_y(j ,k+1)-vol_flux_y(j,k)+vol_flux_x(j+1,k )-vol_flux_x(j,k))
post_vol(j,k)=pre_vol(j,k)-(vol_flux_y(j ,k+1)-vol_flux_y(j,k))
end if
ELSE
if (j <= x_max+2 .and. k <= y_max+2) then
pre_vol(j,k)=volume(j,k)+vol_flux_y(j ,k+1)-vol_flux_y(j,k)
post_vol(j,k)=volume(j,k)
end if
ENDIF
end SUBROUTINE advec_cell_kernel_1y
attributes(global) SUBROUTINE advec_cell_kernel_2x(x_min, &
x_max, &
y_min, &
y_max, &
vertexdx, &
density1, &
energy1, &
mass_flux_x, &
vol_flux_x, &
pre_vol, &
ener_flux )
IMPLICIT NONE
INTEGER, value :: x_min,x_max,y_min,y_max
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: density1
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: energy1
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: vol_flux_x
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: mass_flux_x
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: ener_flux
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3) :: vertexdx
INTEGER :: j,k,upwind,donor,downwind,dif
REAL(KIND=8) :: wind,sigmat,sigmam,sigma3,sigma4
REAL(KIND=8) :: diffuw,diffdw,limiter
REAL(KIND=8) :: one_by_six=1.0_8/6.0_8
j = (blockIdx%x-1)*blockDim%x + threadIdx%x + x_min-1
k = (blockIdx%y-1)*blockDim%y + threadIdx%y + y_min-1
if (j <= x_max+2 .and. k <= y_max) then
IF(vol_flux_x(j,k).GT.0.0)THEN
upwind =j-2
donor =j-1
downwind =j
dif =donor
ELSE
upwind =MIN(j+1,x_max+2)
donor =j
downwind =j-1
dif =upwind
ENDIF
sigmat=ABS(vol_flux_x(j,k))/pre_vol(donor,k)
sigma3=(1.0_8+sigmat)*(vertexdx(j)/vertexdx(dif))
sigma4=2.0_8-sigmat
diffuw=density1(donor,k)-density1(upwind,k)
diffdw=density1(downwind,k)-density1(donor,k)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmat)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
mass_flux_x(j,k)=vol_flux_x(j,k)*(density1(donor,k)+limiter)
sigmam=ABS(mass_flux_x(j,k))/(density1(donor,k)*pre_vol(donor,k))
diffuw=energy1(donor,k)-energy1(upwind,k)
diffdw=energy1(downwind,k)-energy1(donor,k)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmam)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
ener_flux(j,k)=mass_flux_x(j,k)*(energy1(donor,k)+limiter)
end if
end SUBROUTINE advec_cell_kernel_2x
attributes(global) SUBROUTINE advec_cell_kernel_2y(x_min, &
x_max, &
y_min, &
y_max, &
vertexdy, &
density1, &
energy1, &
mass_flux_y, &
vol_flux_y, &
pre_vol, &
ener_flux )
IMPLICIT NONE
INTEGER, value :: x_min,x_max,y_min,y_max
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: density1
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: energy1
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: vol_flux_y
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: mass_flux_y
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: ener_flux
REAL(KIND=8), intent(in), DIMENSION(y_min-2:y_max+3) :: vertexdy
INTEGER :: j,k,upwind,donor,downwind,dif
REAL(KIND=8) :: wind,sigmat,sigmam,sigma3,sigma4
REAL(KIND=8) :: diffuw,diffdw,limiter
REAL(KIND=8) :: one_by_six=1.0_8/6.0_8
j = (blockIdx%x-1)*blockDim%x + threadIdx%x + x_min-1
k = (blockIdx%y-1)*blockDim%y + threadIdx%y + y_min-1
if (j <= x_max .and. k <= y_max+2) then
IF(vol_flux_y(j,k).GT.0.0)THEN
upwind =k-2
donor =k-1
downwind =k
dif =donor
ELSE
upwind =MIN(k+1,y_max+2)
donor =k
downwind =k-1
dif =upwind
ENDIF
sigmat=ABS(vol_flux_y(j,k))/pre_vol(j,donor)
sigma3=(1.0_8+sigmat)*(vertexdy(k)/vertexdy(dif))
sigma4=2.0_8-sigmat
diffuw=density1(j,donor)-density1(j,upwind)
diffdw=density1(j,downwind)-density1(j,donor)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmat)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
mass_flux_y(j,k)=vol_flux_y(j,k)*(density1(j,donor)+limiter)
sigmam=ABS(mass_flux_y(j,k))/(density1(j,donor)*pre_vol(j,donor))
diffuw=energy1(j,donor)-energy1(j,upwind)
diffdw=energy1(j,downwind)-energy1(j,donor)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmam)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
ener_flux(j,k)=mass_flux_y(j,k)*(energy1(j,donor)+limiter)
end if
end SUBROUTINE advec_cell_kernel_2y
attributes(global) SUBROUTINE advec_cell_kernel_3x(x_min, &
x_max, &
y_min, &
y_max, &
density1, &
energy1, &
mass_flux_x, &
vol_flux_x, &
pre_vol, &
pre_mass, &
post_mass, &
advec_vol, &
post_ener, &
ener_flux )
IMPLICIT NONE
INTEGER, value :: x_min,x_max,y_min,y_max
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: density1
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: energy1
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: vol_flux_x
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: mass_flux_x
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_mass
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_mass
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: advec_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_ener
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: ener_flux
INTEGER :: j,k
real(kind=8) :: pre_mass_jk, post_mass_jk, advec_vol_jk, post_ener_jk
j = (blockIdx%x-1)*blockDim%x + threadIdx%x + x_min-1
k = (blockIdx%y-1)*blockDim%y + threadIdx%y + y_min-1
if (j <= x_max .and. k <= y_max) then
pre_mass_jk=density1(j,k)*pre_vol(j,k)
post_mass_jk=pre_mass_jk+mass_flux_x(j,k)-mass_flux_x(j+1,k)
post_ener_jk=(energy1(j,k)*pre_mass_jk+ener_flux(j,k)-ener_flux(j+1,k))/post_mass_jk
advec_vol_jk=pre_vol(j,k)+vol_flux_x(j,k)-vol_flux_x(j+1,k)
density1(j,k)=post_mass_jk/advec_vol_jk
energy1(j,k)=post_ener_jk
end if
END SUBROUTINE advec_cell_kernel_3x
attributes(global) SUBROUTINE advec_cell_kernel_3y(x_min, &
x_max, &
y_min, &
y_max, &
density1, &
energy1, &
mass_flux_y, &
vol_flux_y, &
pre_vol, &
pre_mass, &
post_mass, &
advec_vol, &
post_ener, &
ener_flux )
IMPLICIT NONE
INTEGER, value :: x_min,x_max,y_min,y_max
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: density1
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: energy1
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: vol_flux_y
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: mass_flux_y
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_mass
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_mass
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: advec_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_ener
REAL(KIND=8), intent(in), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: ener_flux
real(kind=8) :: pre_mass_jk, post_mass_jk, post_ener_jk, advec_vol_jk
INTEGER :: j,k
j = (blockIdx%x-1)*blockDim%x + threadIdx%x + x_min-1
k = (blockIdx%y-1)*blockDim%y + threadIdx%y + y_min-1
if (j <= x_max .and. k <= y_max) then
pre_mass_jk=density1(j,k)*pre_vol(j,k)
post_mass_jk=pre_mass_jk+mass_flux_y(j,k)-mass_flux_y(j,k+1)
post_ener_jk=(energy1(j,k)*pre_mass_jk+ener_flux(j,k)-ener_flux(j,k+1))/post_mass_jk
advec_vol_jk=pre_vol(j,k)+vol_flux_y(j,k)-vol_flux_y(j,k+1)
density1(j,k)=post_mass_jk/advec_vol_jk
energy1(j,k)=post_ener_jk
end if
END SUBROUTINE advec_cell_kernel_3y
SUBROUTINE advec_cell_kernel(x_min, &
x_max, &
y_min, &
y_max, &
dir, &
sweep_number,&
vertexdx, &
vertexdy, &
volume, &
density1, &
energy1, &
mass_flux_x, &
vol_flux_x, &
mass_flux_y, &
vol_flux_y, &
pre_vol, &
post_vol, &
pre_mass, &
post_mass, &
advec_vol, &
post_ener, &
ener_flux )
IMPLICIT NONE
INTEGER :: x_min,x_max,y_min,y_max
INTEGER :: sweep_number,dir
INTEGER :: g_xdir=1,g_ydir=2
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: volume
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: density1
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+2) :: energy1
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: vol_flux_x
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: vol_flux_y
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+2) :: mass_flux_x
REAL(KIND=8), DIMENSION(x_min-2:x_max+2,y_min-2:y_max+3) :: mass_flux_y
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: pre_mass
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_mass
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: advec_vol
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: post_ener
REAL(KIND=8), DIMENSION(x_min-2:x_max+3,y_min-2:y_max+3) :: ener_flux
REAL(KIND=8), DIMENSION(x_min-2:x_max+3) :: vertexdx
REAL(KIND=8), DIMENSION(y_min-2:y_max+3) :: vertexdy
INTEGER :: j,k,upwind,donor,downwind,dif
REAL(KIND=8) :: wind,sigmat,sigmam,sigma3,sigma4
REAL(KIND=8) :: diffuw,diffdw,limiter
REAL(KIND=8) :: one_by_six=1.0_8/6.0_8
IF(dir.EQ.g_xdir) THEN
IF(sweep_number.EQ.1)THEN
DO k=y_min-2,y_max+2
DO j=x_min-2,x_max+2
pre_vol(j,k)=volume(j,k)+(vol_flux_x(j+1,k )-vol_flux_x(j,k)+vol_flux_y(j ,k+1)-vol_flux_y(j,k))
post_vol(j,k)=pre_vol(j,k)-(vol_flux_x(j+1,k )-vol_flux_x(j,k))
ENDDO
ENDDO
ELSE
DO k=y_min-2,y_max+2
DO j=x_min-2,x_max+2
pre_vol(j,k)=volume(j,k)+vol_flux_x(j+1,k)-vol_flux_x(j,k)
post_vol(j,k)=volume(j,k)
ENDDO
ENDDO
ENDIF
DO k=y_min,y_max
DO j=x_min,x_max+2
IF(vol_flux_x(j,k).GT.0.0)THEN
upwind =j-2
donor =j-1
downwind =j
dif =donor
ELSE
upwind =MIN(j+1,x_max+2)
donor =j
downwind =j-1
dif =upwind
ENDIF
sigmat=ABS(vol_flux_x(j,k))/pre_vol(donor,k)
sigma3=(1.0_8+sigmat)*(vertexdx(j)/vertexdx(dif))
sigma4=2.0_8-sigmat
diffuw=density1(donor,k)-density1(upwind,k)
diffdw=density1(downwind,k)-density1(donor,k)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmat)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
mass_flux_x(j,k)=vol_flux_x(j,k)*(density1(donor,k)+limiter)
sigmam=ABS(mass_flux_x(j,k))/(density1(donor,k)*pre_vol(donor,k))
diffuw=energy1(donor,k)-energy1(upwind,k)
diffdw=energy1(downwind,k)-energy1(donor,k)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmam)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
ener_flux(j,k)=mass_flux_x(j,k)*(energy1(donor,k)+limiter)
ENDDO
ENDDO
DO k=y_min,y_max
DO j=x_min,x_max
pre_mass(j,k)=density1(j,k)*pre_vol(j,k)
post_mass(j,k)=pre_mass(j,k)+mass_flux_x(j,k)-mass_flux_x(j+1,k)
post_ener(j,k)=(energy1(j,k)*pre_mass(j,k)+ener_flux(j,k)-ener_flux(j+1,k))/post_mass(j,k)
advec_vol(j,k)=pre_vol(j,k)+vol_flux_x(j,k)-vol_flux_x(j+1,k)
density1(j,k)=post_mass(j,k)/advec_vol(j,k)
energy1(j,k)=post_ener(j,k)
ENDDO
ENDDO
ELSEIF(dir.EQ.g_ydir) THEN
IF(sweep_number.EQ.1)THEN
DO k=y_min-2,y_max+2
DO j=x_min-2,x_max+2
pre_vol(j,k)=volume(j,k)+(vol_flux_y(j ,k+1)-vol_flux_y(j,k)+vol_flux_x(j+1,k )-vol_flux_x(j,k))
post_vol(j,k)=pre_vol(j,k)-(vol_flux_y(j ,k+1)-vol_flux_y(j,k))
ENDDO
ENDDO
ELSE
DO k=y_min-2,y_max+2
DO j=x_min-2,x_max+2
pre_vol(j,k)=volume(j,k)+vol_flux_y(j ,k+1)-vol_flux_y(j,k)
post_vol(j,k)=volume(j,k)
ENDDO
ENDDO
ENDIF
DO k=y_min,y_max+2
DO j=x_min,x_max
IF(vol_flux_y(j,k).GT.0.0)THEN
upwind =k-2
donor =k-1
downwind =k
dif =donor
ELSE
upwind =MIN(k+1,y_max+2)
donor =k
downwind =k-1
dif =upwind
ENDIF
sigmat=ABS(vol_flux_y(j,k))/pre_vol(j,donor)
sigma3=(1.0_8+sigmat)*(vertexdy(k)/vertexdy(dif))
sigma4=2.0_8-sigmat
diffuw=density1(j,donor)-density1(j,upwind)
diffdw=density1(j,downwind)-density1(j,donor)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmat)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
mass_flux_y(j,k)=vol_flux_y(j,k)*(density1(j,donor)+limiter)
sigmam=ABS(mass_flux_y(j,k))/(density1(j,donor)*pre_vol(j,donor))
diffuw=energy1(j,donor)-energy1(j,upwind)
diffdw=energy1(j,downwind)-energy1(j,donor)
wind=1.0_8
IF(diffdw.LE.0.0) wind=-1.0_8
IF(diffuw*diffdw.GT.0.0)THEN
limiter=(1.0_8-sigmam)*wind*MIN(ABS(diffuw),ABS(diffdw)&
,one_by_six*(sigma3*ABS(diffuw)+sigma4*ABS(diffdw)))
ELSE
limiter=0.0
ENDIF
ener_flux(j,k)=mass_flux_y(j,k)*(energy1(j,donor)+limiter)
ENDDO
ENDDO
DO k=y_min,y_max
DO j=x_min,x_max
pre_mass(j,k)=density1(j,k)*pre_vol(j,k)
post_mass(j,k)=pre_mass(j,k)+mass_flux_y(j,k)-mass_flux_y(j,k+1)
post_ener(j,k)=(energy1(j,k)*pre_mass(j,k)+ener_flux(j,k)-ener_flux(j,k+1))/post_mass(j,k)
advec_vol(j,k)=pre_vol(j,k)+vol_flux_y(j,k)-vol_flux_y(j,k+1)
density1(j,k)=post_mass(j,k)/advec_vol(j,k)
energy1(j,k)=post_ener(j,k)
ENDDO
ENDDO
ENDIF
END SUBROUTINE advec_cell_kernel
END MODULE advec_cell_kernel_module