-
Notifications
You must be signed in to change notification settings - Fork 2
/
build.gradle
182 lines (159 loc) · 7.08 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
import org.ajoberstar.grgit.*
plugins {
id 'java'
id "org.javamodularity.moduleplugin" version "1.8.8"
id 'org.springframework.boot' version '2.5.4'
id 'io.spring.dependency-management' version '1.0.11.RELEASE'
id "org.beryx.jlink" version "2.24.1"
id "org.ajoberstar.grgit" version "4.1.0"
}
sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11
tasks.withType(JavaCompile) {
options.encoding = 'UTF-8'
}
configurations {
compileOnly {
extendsFrom annotationProcessor
}
}
repositories {
mavenCentral()
}
defaultTasks 'clean', 'jlinkZip'
configurations {
springFactoriesHolder { transitive = false }
}
dependencies {
springFactoriesHolder 'org.springframework.boot:spring-boot-actuator-autoconfigure'
springFactoriesHolder 'org.springframework.boot:spring-boot-autoconfigure'
springFactoriesHolder 'org.springframework.boot:spring-boot'
implementation 'org.springframework.boot:spring-boot-starter-actuator'
implementation 'org.springframework.boot:spring-boot-starter-cache'
implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
implementation 'org.springframework.boot:spring-boot-starter-web'
implementation 'org.springframework.boot:spring-boot-starter-validation'
implementation 'com.sun.activation:jakarta.activation:2.0.1'
implementation 'javax.annotation:javax.annotation-api:1.3.2'
implementation 'org.hsqldb:hsqldb'
implementation 'javax.cache:cache-api'
implementation 'org.ehcache:ehcache'
implementation 'org.webjars:webjars-locator-core'
implementation 'org.webjars:jquery:2.2.4'
implementation 'org.webjars:jquery-ui:1.11.4'
implementation 'org.webjars:bootstrap:3.3.6'
}
application {
mainClass = 'org.springframework.samples.petclinic.PetClinicApplication'
mainModule = 'org.springframework.samples.petclinic'
}
// This task clones the spring-petclinic project and adds module-info.java to it.
// The commitId is configured in gradle.properties.
task clonePetclinic {
def cloneDir = "$buildDir/clone"
outputs.dir(cloneDir)
inputs.property("commitId", commitId)
doLast {
project.logger.info("Deleting ${cloneDir}...")
delete(cloneDir)
project.logger.info("Cloning spring-petclinic...")
def grgit = Grgit.clone(dir: cloneDir, uri: "https://github.com/spring-projects/spring-petclinic.git")
project.logger.debug("grgit: $grgit")
project.logger.info("Resolving commit $commitId")
def commitObj = grgit.resolve.toCommit(commitId)
project.logger.debug("commitObj: $commitObj")
grgit.reset(commit: commitObj, mode: 'soft')
copy {
from 'resources/module-info.java'
into "$cloneDir/src/main/java"
}
ant.move file: "$cloneDir/src", todir: "."
}
}
compileJava.dependsOn 'clonePetclinic'
tasks.jar.enabled = true
prepareMergedJarsDir.doLast {
// extract and merge META-INF/spring.factories from springFactoriesHolder
def factories = configurations.springFactoriesHolder.files.collect {
def props = new Properties()
props.load(zipTree(it).matching { include 'META-INF/spring.factories' }.singleFile.newInputStream())
props
}
def mergedProps = new Properties()
factories.each { props ->
props.each { key, value ->
def oldVal = mergedProps[key]
mergedProps[key] = oldVal ? "$oldVal,$value" : value
}
}
def content = mergedProps.collect { key, value ->
def v = (value as String).replace(',', ',\\\n')
"$key=$v"
}.join('\n\n')
mkdir("$jlinkBasePath/META-INF")
new File("$jlinkBasePath/META-INF/spring.factories").text = content
// insert META-INF/spring.factories into the main jar
ant.zip(update: "true", destfile: jar.archivePath, keepcompression: true) {
fileset(dir: "$jlinkBasePath", includes: 'META-INF/**')
}
}
jlink {
imageZip = file("$buildDir/image-zip/spring-petclinic-image.zip")
forceMerge 'jaxb-api', 'byte-buddy', 'classgraph', 'tomcat'
mergedModule {
uses 'ch.qos.logback.classic.spi.Configurator'
uses 'javax.validation.valueextraction.ValueExtractor'
uses 'javax.validation.ConstraintValidator'
uses 'org.ehcache.core.spi.service.ServiceFactory'
uses 'org.ehcache.xml.CacheManagerServiceConfigurationParser'
uses 'org.ehcache.xml.CacheServiceConfigurationParser'
uses 'org.hibernate.integrator.spi.Integrator'
uses 'org.hibernate.boot.registry.selector.StrategyRegistrationProvider'
uses 'org.hibernate.service.spi.ServiceContributor'
uses 'org.hibernate.boot.spi.MetadataSourcesContributor'
uses 'org.hibernate.boot.spi.MetadataBuilderInitializer'
uses 'org.hibernate.boot.spi.MetadataBuilderFactory'
uses 'org.hibernate.boot.model.TypeContributor'
uses 'org.hibernate.boot.spi.MetadataContributor'
uses 'org.hibernate.boot.spi.AdditionalJaxbMappingProducer'
uses 'org.hibernate.boot.spi.SessionFactoryBuilderFactory'
uses 'org.hibernate.service.spi.SessionFactoryServiceContributor'
excludeRequires 'com.fasterxml.jackson.module.paramnames'
excludeProvides implementation: 'com.sun.xml.bind.v2.ContextFactory'
excludeProvides servicePattern: 'javax.enterprise.inject.*'
excludeProvides service: 'org.apache.logging.log4j.spi.Provider'
excludeProvides service: 'reactor.blockhound.integration.BlockHoundIntegration'
excludeProvides service: 'org.apache.logging.log4j.util.PropertySource'
}
options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
launcher{
jvmArgs = [
'--add-opens', 'java.base/java.lang=spring.petclinic.merged.module',
'--add-opens', 'java.base/java.io=spring.petclinic.merged.module',
'-cp', 'config/',
'-Dspring.datasource.schema=file:config/db/hsqldb/schema.sql',
'-Dspring.datasource.data=file:config/db/hsqldb/data.sql',
'-Dspring.jpa.hibernate.ddl-auto=none',
'-Dspring.messages.basename=messages/messages'
]
}
}
tasks.jlink.doLast {
// Spring performs its magic by scanning the classpath, but in a modular application the classpath is replaced by the module-path.
// To circumvent this problem, we copy all resources into the 'config' directory and set this directory as classpath.
copy {
from "src/main/resources"
into "$imageDir.asFile/bin/config"
}
copy {
from 'resources/css'
into "$imageDir.asFile/bin/config/static/resources/css"
}
// Spring also needs to read the .class files, therefore they should be accessible via classpath.
// Note: These .class files are only used as resources, they will not be loaded by a classloader.
copy {
from "$buildDir/classes/java/main/org/springframework/samples/petclinic"
into "$imageDir.asFile/bin/config/org/springframework/samples/petclinic/for-spring-classpath-scanner"
}
}