Unexpected String -> Array[String] coercion

[danxmoran]

Cromwell version: 30-9a7de06

Minimized from one of our WDLs:

workflow Test {
  Boolean do
  Int n

  if (do) {
    call Optional
  }

  scatter (i in range(n)) {
    call Scattered
  }

  call Gather {
    input:
      # HERE: select_first returns String, and Scattered.out is an Array[String]
      ins = if defined(Optional.out) then select_first([Optional.out]) else Scattered.out
  }
  output {
    Gather.out
  }
}

task Optional {
  command {
    echo "Hey!"
  }
  output {
    String out = read_string(stdout())
  }
}

task Scattered {
  command {
    echo "Hello!"
  }
  output {
    String out = read_string(stdout())
  }
}

task Gather {
  Array[String] ins

  command {
    cat ${write_lines(ins)}
  }
  output {
    String out = read_string(stdout())
  }
}

This WDL runs successfully, but in code review I noticed the weird type mismatch between the branches. I asked @cjllanwarne about it and he thought it was an old "feature" that had been purged to avoid bugs / confusion. I'd expect something like this to be rejected.