Matching inner blocks with PUSH and POP

[periode]

Hello,

First of all, thanks a lot for the work on Pest, it's a pleasure to work with!

I'm relatively new to writing PEGs, and I'm encountering a hurdle in parsing nested blocks.

Specifically, I would like to parse ( a small, defined subset of) LaTeX, and I'm having an issue at properly parsing nested \begin{} and \end{} pairs:

\begin{document}

Some text.

\begin{quote}
  A quote.
\end{quote}


\end{document}

The expected parse tree would be something along the lines of:

- env
-  - expression
-  - env
-  -  - expression

But what I get instead is the second \begin{quote} block gets parsed as a command statement, rather than as a block statement:

- env
- - expression
- - command
- - expression
- - command

Here's the grammar:

// Top level rule is `document`.
document = { 
    SOI ~
    (section? ~ newline_char)* ~ section? ~
    EOI
}

section = {
    env_stmt |
    cmd_stmt |
    expression
}

// Expression grammar
expression   = { ( cmd_stmt | literal )* }
literal      = @{ char+ }
char         = @{ ASCII_ALPHANUMERIC | punctuation }
punctuation  = {
    "," | "." | ";" | "(" | ")" | "[" | "]" | "|" | "<" | ">" | ":" 
}

// Control Statement Grammar
cmd_stmt = { ctrl_character ~ name ~ cmd_stmt_opt? ~ "{" ~ expression ~ "}" }
cmd_stmt_opt = { "[" ~ name ~ "]" }

name                    = @{ ASCII_ALPHA+ }
COMMENT                 = _{ "%" ~ (!newline_char ~ ANY)* ~ newline_char }
WHITESPACE              = _{ " " }
newline_char            = _{"\n"}
ctrl_character       = _{ "\\" }

// Environment Grammar
env_stmt     = { env_begin ~ env_content ~ env_end }
env_content  = { (section? ~ newline_char)* }
env_begin    = @{ ctrl_character ~ "begin" ~ "{" ~ PUSH(name) ~ "}" }
env_end      = @{ ctrl_character ~ "end" ~ "{" ~ PEEK ~ "}" }

I'm guessing it has something to do with PUSH/PEEK. When I remove them, only the inner block gets parsed as an environment, the outer one is parsed as a control statement.

Could someone please point me towards what I'm doing wrong?

Thanks!

[S0AndS0]

I recently published a post about nested PUSH/POP trickery, and a few gotchas too.

TLDR

Here's a minimalistic/naive set of pest configurations that should allow for nested blocks of code begin/end tags that may, or may not, contain raw text too.

//! title: Nested PUSH/POP minimal example for LaTeX (like) syntax
//! licence: AGPL-3.0
//! author: [S0AndS0](https://github.com/S0AndS0)

document = { SOI ~ node* ~ EOI }

node    = _{ latex | content }
content =  { ( !(end | begin | latex) ~ ANY )+ }
latex   =  { begin ~ (!end ~ node)* ~ end }

name  =  { (!"}" ~ ASCII_ALPHA)+ }
begin = ${ "\\begin{" ~ PUSH(name) ~ "}" }
end   = @{ "\\end{" ~ POP ~ "}" }

Example input

outer before
\begin{foo}
foo before
\begin{bar}
inner bar
\end{bar}
foo after
\end{foo}
outer after

Parser result

- document
  - content: "outer before\n"
  - latex
    - begin > name: "foo"
    - content: "\nfoo before\n"
    - latex
      - begin > name: "bar"
      - content: "\ninner bar\n"
      - end: "\\end{bar}"
    - content: "\nfoo after\n"
    - end: "\\end{foo}"
  - content: "\nouter after"

---

Check the previously linked post for line-by-line explanations of, what I currently understand, of Pest's behaviors. And one warning regarding the POP-ing of an empty stack causing panic.