-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
183 lines (160 loc) · 5.33 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
{
inputs = {
### Globally auto-updated ###
latest.url = "nixpkgs/nixos-24.05"; # used by VPSs & microvms for security's sake, updated every 24h (or less)
latest-unstable.url = "nixpkgs/nixos-unstable";
disko.url = "github:nix-community/disko"; #TODO: use disko for desktops & servers
disko.inputs.nixpkgs.follows = "latest";
sops-nix.url = "github:Mic92/sops-nix"; #TODO: auto-update
sops-nix.inputs.nixpkgs.follows = "latest";
### Manually updated ###
# Desktops
desktop.url = "nixpkgs/nixos-unstable"; #TODO: setup auto-update?
home-manager.url = "github:nix-community/home-manager/master";
home-manager.inputs.nixpkgs.follows = "desktop";
# Servers
server.url = "nixpkgs/nixos-24.05"; #TODO: setup auto-update?
server-unstable.url = "nixpkgs/nixos-unstable";
microvm.url = "github:astro/microvm.nix";
microvm.inputs.nixpkgs.follows = "server";
};
outputs = inputs @ {
self,
latest,
latest-unstable,
disko,
desktop,
home-manager,
server,
server-unstable,
microvm,
sops-nix,
}: let
inherit (self) outputs;
in {
formatter.x86_64-linux = latest.legacyPackages.x86_64-linux.alejandra;
formatter.aarch64-linux = latest.legacyPackages.aarch64-linux.alejandra;
### Hosts ###
nixosConfigurations = let
# Stuff shared between all presets
shared = {
modules = [
# MicroVM
microvm.nixosModules.host
microvm.nixosModules.microvm
{
microvm = {
guest.enable = false; # the microvm modules need to be imported,
host.enable = false; # but should only be enabled when necessary
};
}
# Misc. modules
disko.nixosModules.disko
home-manager.nixosModules.home-manager
sops-nix.nixosModules.sops
# options.cfg.* declarations
./config
];
extraArgs = {
inherit inputs outputs;
misc = {};
};
};
in
builtins.mapAttrs (name: host: let
nixpkgs = host.channels.nixpkgs;
unstable = host.channels.unstable or nixpkgs;
in
nixpkgs.ref.lib.nixosSystem rec {
system = host.system;
pkgs = import nixpkgs.ref {
inherit system;
config = nixpkgs.config or {};
};
specialArgs =
{
configLib = import ./lib {inherit (nixpkgs.ref) lib;}; # configLib.relativeToRoot is used in imports, therefore needs to be in specialArgs
unstable = import unstable.ref {
inherit system;
config = unstable.config or {};
};
}
// (host.specialArgs or {});
modules =
shared.modules
++ (host.modules or [])
++ [
{_module.args = shared.extraArgs // (host.extraArgs or {});}
./hosts/${host.preset}/${host.hostName or name}
./presets/${host.preset}.nix
];
}) (
builtins.listToAttrs (
#
# Desktops
#
(map (name: {
inherit name;
value = {
system = "x86_64-linux";
preset = "desktop";
channels.nixpkgs.ref = desktop;
channels.nixpkgs.config.allowUnfree = true;
};
}) (builtins.attrNames (builtins.readDir ./hosts/desktop)))
++
#
# Physical servers
#
(map (name: {
inherit name;
value = {
system = "x86_64-linux";
preset = "server";
channels.nixpkgs.ref = server;
channels.unstable.ref = server-unstable;
};
}) (builtins.attrNames (builtins.readDir ./hosts/server)))
++
#
# ARM VPSs
#
(map (name: {
inherit name;
value = {
system = "aarch64-linux";
preset = "vps";
channels.nixpkgs.ref = latest;
channels.unstable.ref = latest-unstable;
};
}) (builtins.attrNames (builtins.readDir ./hosts/vps)))
++
#
# MicroVMs
#
(latest.lib.lists.concatMap (hypervisorName: (
map (selfName: {
name = "${hypervisorName}:${selfName}";
value = rec {
hostName = selfName;
system = "x86_64-linux";
preset = "microvm";
channels.nixpkgs.ref = latest;
channels.unstable.ref = latest-unstable;
channels.nixpkgs.config.allowUnfreePredicate = pkg:
builtins.elem (channels.nixpkgs.ref.lib.getName pkg) [
"zerotierone"
];
channels.unstable.config.allowUnfreePredicate = pkg:
builtins.elem (channels.unstable.ref.lib.getName pkg) [
"factorio-headless"
];
modules = [./hosts/server/${hypervisorName}/meta.nix];
extraArgs.misc = {inherit hypervisorName selfName;};
};
}) (builtins.attrNames (builtins.readDir ./hosts/microvm))
)) (builtins.attrNames (builtins.readDir ./hosts/server)))
)
);
};
}