V example on compare#go isn't uptodate

[Heribert17]

Due to syntax changes the example doesn't compile out of the box (? is deprecated and http.Response doesn't have a text field).
So I updated the example:

module main

import net.http
import json

const (
	stories_url   = 'https://hacker-news.firebaseio.com/v0/topstories.json'
	item_base_url = 'https://hacker-news.firebaseio.com/v0/item'
)

struct Story {
	title string
}

struct Cursor {
mut:
	pos int
}

fn main() {
	resp := http.get(stories_url)!
	ids := json.decode([]int, resp.body)!
	shared cursor := Cursor{}
	mut threads := []thread{}

	for _ in 0 .. 8 {
		threads << go fn (ids []int, shared cursor Cursor) {
			for {
				id := lock cursor {
					if cursor.pos >= ids.len {
						break
					}
					cursor.pos++
					ids[cursor.pos - 1]
				}
				resp := http.get('$item_base_url/${id}.json') or { panic(err) }
				story := json.decode(Story, resp.body) or { panic(err) }
				println(story.title)
			}
		}(ids, shared cursor)
	}
	threads.wait()
}

[larpon]

Can you please link to where this example comes from? Our CI should catch such regressions before they end up in the master branch

[JalonSolov]

That's from the Comparing V to Go section of the Wiki, not in any of the code touched by PRs, CI, etc. Perhaps it should be, but it isn't now. :-)

[larpon]

Thanks @JalonSolov - yes maybe they should be 😄