Custom Buffer Type using Parametric Polymorphism

[herohiralal]

I have the following struct (for interop purposes):

FixedSizeBuffer :: struct($T: typeid, $SIZE: u64) {
    count:  u64,
    buffer: [SIZE]T,
}

And I have a few different procedures for it (examples):

get_capacity :: proc(buffer: ^$T/FixedSizeBuffer) -> u64 {
    return T.SIZE
}

get_count :: proc(buffer: ^$T/FixedSizeBuffer) -> u64 {
    return buffer.count
}

I would like to create this procedure:

access :: proc(buffer: ^$T/FixedSizeBuffer, index: u64) -> ^$T2 {
    return &buffer.buffer[index]
}

And use it like this:

item := collections.access(&myBuffer, 3)

But this throws the following error:

Error: Invalid use of a polymorphic type '^$T2' in variable declaration
        item := collections.access(&myBuffer, 3)
        ^

Can someone please help me out with this.

[Kelimion]

FixedSizeBuffer :: struct($E: typeid, $SIZE: u64) {
	count:  u64,
	buffer: [SIZE]E,
}

// Didn't need a pointer
get_capacity :: proc(buffer: $B/FixedSizeBuffer) -> u64 {
	return B.SIZE
}

// Didn't need a pointer
get_count :: proc(buffer: $B/FixedSizeBuffer) -> u64 {
	return buffer.count
}

// What was $T2 supposed to be? You can't have a $ return value.
get_slot :: proc(buffer: ^$B/FixedSizeBuffer($E, $S), index: u64) -> ^E {
	if index < buffer.count {
		return &buffer.buffer[index]
	}
	return nil
}

_main :: proc() {
	fsb: FixedSizeBuffer(string, 5)
	fmt.println(fsb)
	fmt.println(get_capacity(fsb))
	fmt.println(get_count(fsb))
	fmt.println(get_slot(&fsb, 2)) // returns nil because buffer.count < 2
}

[Kelimion]

Please don't ping us in two places (Discord and GitHub) about the same question.